home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Video Toaster 4.3
/
Video Toaster v4.3.iso
/
3.1
/
toasterall
/
arexx_examples
/
tpaint
/
embossborder.rexx
< prev
next >
Wrap
OS/2 REXX Batch file
|
1992-01-29
|
1KB
|
57 lines
/* EmbossBorder.rexx Make 3D style frame in ToasterPaint */
/* By Arnie Cachelin © 1992 NewTek Inc */
/* 02 Jan 1992 At 10:39:31 */
/*
This program will draw a raised, 3D-look border on the ToasterPaint canvas
using the lighten and darken modes. Specify the position of the upper left
corner, the outer width and height, and the border thickness.
*/
arg x y Width Height Thick
Address 'DigiPaint'
if pos('DigiPaint',show(ports))=0 then do
say "Can't find ToasterPaint!"
exit
end
if Arg()=0 then do
say "Usage: rx EmbossBorder x y width height thickness"
exit
end
if x="" then x=0
if y="" then y=0
if Width="" then Width=752
if Height="" then Height=480
if Thick="" then Thick=10
call EmbossBorder(x, y, Width, Height, Thick)
exit
EmbossBorder: PROCEDURE
arg x, y, Width, Height, Thick
'Pmcl' /* Normal paint mode */
'Flof' /* Filled Shapes Mode Off */
'Dotb' /* One pixel brush */
'Bsmo' /* Smooth Draw Mode */
do i=0 to thick
x1=x+i
y1=y+i
x2=x+Width-i
y2=y+Height-i
'Pmln' /* Lighten Mode */
'Pend' x2 y1 /* top */
'Move' x1 y1
'Move' x1 y2
'Penu' x1 y2 /* Left */
'Pmdn' /* Darken Mode */
'Pend' x2 y1 /* Right */
'Move' x2 y2
'Move' x1 y2
'Penu' x1 y2 /* Bottom */
end i
return 0